---
title: "Lista all info ur en tabell inkl fältnamnen"
type: "forum-thread"
url: "https://www.webforum.nu/amne/asp/114129-lista-all-info-ur-en-tabell-inkl-fältnamnen"
topic: "ASP"
topic_url: "https://www.webforum.nu/amne/asp"
author: "Davida"
published: "2004-10-22T06:19:00.000Z"
updated: "2004-10-22T07:41:03.000Z"
replies: 2
views: 322
page: 1
pages: 1
language: "sv-SE"
site: "webForum — webforum.nu"
rights: "Upphovsrätten till varje inlägg tillhör dess författare."
attribution: "Citera som: webForum, https://www.webforum.nu/amne/asp/114129-lista-all-info-ur-en-tabell-inkl-fältnamnen"
---

# Lista all info ur en tabell inkl fältnamnen

## #1 — Davida, 2004-10-22T06:19Z

Hej!

Jag söker efter ett skript som skriver ut allt innehåll ur en tabell, det har funnits här innan, men jag kan inte hitta det.

Är det nån som har en kopia på det?

MVH
David

Permalänk: https://www.webforum.nu/p/114129

## #2 — Palle, 2004-10-22T06:27Z

Snabbexempel a´la MS Access: 

```
[red]Set Connect = Server.CreateObject("ADODB.Connection")
	Connect.Open "Provider=Microsoft.Jet.OLEDB.4.0;Data Source ="& Server.MapPath("databas.mdb")
		Set RecSet = Connect.Execute("SELECT * FROM tabell")

			If NOT RecSet.EOF Then
				Do Until RecSet.EOF
					Response.Write RecSet("KOLUMNENS_NAMN") &"<br>"
					RecSet.MoveNext
				Loop
			Else
				Response.Write "Det finns inget att skriva ut."
			End If
			RecSet.Close

		Set RecSet = Nothing
	Connect.Close
Set Connect = Nothing[/red]
```

Permalänk: https://www.webforum.nu/p/1466428

## #3 — @nders, 2004-10-22T07:41Z

Eftersom jag tror att Palle missuppfattade frågan så modifierar jag hans exempel en aning. ;)

```
Set Connect = Server.CreateObject("ADODB.Connection")
Connect.Open "Provider=Microsoft.Jet.OLEDB.4.0;Data Source ="& Server.MapPath("databas.mdb")
Set RecSet = Connect.Execute("SELECT * FROM tabell")
If NOT RecSet.EOF Then
	Response.write "<table><tr>"
	For i = 0 to RecSet.Fields.Count -1
		Response.write "<th>" & RecSet.Fields(i).Name & "</th>"
	Next
	Response.write "</tr>"
	Do Until RecSet.EOF
		Response.write "<tr>"
		For i = 0 to RecSet.Fields.Count -1
			Response.Write "<td>" & RecSet.Fields(i).Value & "</td>"
		Next
		Response.write "</tr>"
		RecSet.MoveNext
	Loop
	Response.write "</table>"
Else
	Response.Write "Det finns inget att skriva ut."
End If
RecSet.Close
Set RecSet = Nothing
Connect.Close
Set Connect = Nothing
```

Helt otestat, naturligtvis.

(Jag var inte helt nöjt med Palles indentering heller, som synes. ;-) )

mvh

Permalänk: https://www.webforum.nu/p/1466450

---

Tråden på webben: https://www.webforum.nu/amne/asp/114129-lista-all-info-ur-en-tabell-inkl-fältnamnen