Fråga gällande paging

SimOnlineMedlem sedan juli 20031 132 inlägg

Frågan17 juli 2004 19:49#1

Hej!

Jag använder mig av en paging från Juicy Studio.

Den ser ut ungefär så här: « ‹ |1 | 2 | 3 | › »

Hur ska jag göra för att begränsa antalet siffror mellan taggarna? Utan begränsning kommer ju pagingen ta upp hela sidan när antalet poster blir för många.

Här kommer koden:

<% @ language="vbscript" %>
<% Option Explicit %>
<% Response.Buffer=True %>
<!-- #include file="adovbs.inc" -->
<%
    Dim strDBVirtualPath, strDBLocation, strConnect, strSQL
    Dim pageNo, i, limit
    Dim objConn, objRS
    strDBVirtualPath="db/yourDB.mdb"
    strDBLocation=Server.MapPath(strDBVirtualPath)
    strConnect="Provider=Microsoft.Jet.OLEDB.4.0;Data Source=" & strDBLocation
    ' Retrieve the page information
    pageNo = CInt(Request.QueryString("pNum"))
    ' If it's zero, it's the first time to this page so put them on page 1
    If pageNo = 0 Then
        pageNo = 1
    End If
    ' Open the database
    Set objConn = Server.CreateObject("ADODB.Connection")
    objConn.Open strConnect
    ' Open the Recordset
    Set objRS = Server.CreateObject("ADODB.RecordSet")
    strSQL = "SELECT * FROM someTable"
    objRS.Open strSQL, objconn, adOpenStatic, adLockReadOnly, adCmdText
    ' Set the page size to 10 records
    objRS.PageSize = 10
    ' Move to the requested page
    objRS.Move (pageNo - 1) * objRS.PageSize
    ' Work out how many records are in this page
    If objRS.AbsolutePage < objRS.PageCount Then
        limit = objRS.PageSize
    Else
        limit = objRS.RecordCount - objRS.PageCount * objRS.PageSize + objRS.PageSize
    End If
%>
<!DOCTYPE HTML PUBLIC "-//W3C//DTD HTML 4.01//EN"
            "http://www.w3.org/TR/html4/strict.dtd">
<html>
<head>
    <title>Record Paging Example</title>
    <meta http-equiv="Content-Type" content="text/html; charset=ISO-8859-1">
</head>
<body>
<p>
<%
    ' Display the records
    For i = 1 To limit
        Response.Write objRS.Fields("yourField").Value & "<br>"
        objRS.MoveNext
    Next
    ' Add page navigation
    Response.Write "<p><a href=""paging.asp?pNum=1"">First Page</a> "
    If pageNo > 1 Then
        Response.Write "<a href=""paging.asp?pNum=" & pageNo - 1 & """>Previous Page</a> "
    End If
    If pageNo < objRS.PageCount Then
        Response.Write "<a href=""paging.asp?pNum=" & pageNo + 1 & """>Next Page</a> "
    End If
    Response.Write "<a href=""paging.asp?pNum=" & objRS.PageCount & """>Last Page</a><br>"
    ' Display each page as a link, apart from the current page
    For i = 1 To objRS.Pagecount
        If i <> pageNo Then
            Response.Write "<a href=""paging.asp?pNum=" & i & """>" & i & "</a> | "
        Else
            Response.Write i & " | "
        End If
    Next
    ' Tidy up
    objRS.Close
    Set objRS = Nothing
    objConn.Close
    Set objConn = Nothing
%>
</p>
</body>
</html>

Tack på förhand