---
title: "Kataloger"
type: "forum-thread"
url: "https://www.webforum.nu/amne/asp/103294-kataloger"
topic: "ASP"
topic_url: "https://www.webforum.nu/amne/asp"
author: "ooostfralla"
published: "2004-05-10T11:30:46.000Z"
updated: "2004-05-10T11:49:43.000Z"
replies: 1
views: 277
page: 1
pages: 1
language: "sv-SE"
site: "webForum — webforum.nu"
rights: "Upphovsrätten till varje inlägg tillhör dess författare."
attribution: "Citera som: webForum, https://www.webforum.nu/amne/asp/103294-kataloger"
---

# Kataloger

## #1 — ooostfralla, 2004-05-10T11:30Z

Hej 
Jag vill kontrollera alla under mappar till en katalog. Jag vet att man kan använda object.Subfolders. Men då kontrollerar man bara ett steg ned.. Däför undrar jag finns det något annan funktionen som kontrollerar hela strukturen och lägger detta i ett objekt.

Permalänk: https://www.webforum.nu/p/103294

## #2 — Jesper T, 2004-05-10T11:49Z

```
function GetSubFolders(pfolder)
    Dim sFolders, fldr, fil
    sFolders = "<LI>" & pfolder.Name

    If pfolder.SubFolders.Count > 0 Or pfolder.Files.Count > 0 Then _
        sFolders = sFolders & "<UL>"

    For Each fldr In pfolder.SubFolders
        sFolders = sFolders & GetSubFolders(fldr)
    Next
    
    For Each fil In pfolder.Files
        sFolders = sFolders & "<LI>" & fil.Name & "</LI>"
    Next
    
    If pfolder.SubFolders.Count > 0 Or pfolder.Files.Count > 0 Then _
        sFolders = sFolders & "</UL>"
    
    sFolders = sFolders & "</LI>"

    Set fil = Nothing
    Set fldr = Nothing
    
    GetSubFolders = sFolders
End function

Dim rootname, fso, folder
rootname = server.mappath("mina_filer")& "\"
Set fso = Server.CreateObject("Scripting.FileSystemObject")
Set folder = fso.GetFolder(rootname)

Response.Write "<UL>" &  GetSubFolders(folder) & "</UL>"
```

Permalänk: https://www.webforum.nu/p/1343938

---

Tråden på webben: https://www.webforum.nu/amne/asp/103294-kataloger