Kataloger — webForum

ooostfrallaMedlem sedan nov. 200250 inlägg

Trådstart10 maj 2004 11:30#1

Hej
Jag vill kontrollera alla under mappar till en katalog. Jag vet att man kan använda object.Subfolders. Men då kontrollerar man bara ett steg ned.. Däför undrar jag finns det något annan funktionen som kontrollerar hela strukturen och lägger detta i ett objekt.

Jesper TMedlem sedan nov. 20017 144 inlägg

10 maj 2004 11:49#2

function GetSubFolders(pfolder)
    Dim sFolders, fldr, fil
    sFolders = "<LI>" & pfolder.Name

    If pfolder.SubFolders.Count > 0 Or pfolder.Files.Count > 0 Then _
        sFolders = sFolders & "<UL>"

    For Each fldr In pfolder.SubFolders
        sFolders = sFolders & GetSubFolders(fldr)
    Next
    
    For Each fil In pfolder.Files
        sFolders = sFolders & "<LI>" & fil.Name & "</LI>"
    Next
    
    If pfolder.SubFolders.Count > 0 Or pfolder.Files.Count > 0 Then _
        sFolders = sFolders & "</UL>"
    
    sFolders = sFolders & "</LI>"

    Set fil = Nothing
    Set fldr = Nothing
    
    GetSubFolders = sFolders
End function

Dim rootname, fso, folder
rootname = server.mappath("mina_filer")& "\"
Set fso = Server.CreateObject("Scripting.FileSystemObject")
Set folder = fso.GetFolder(rootname)

Response.Write "<UL>" &  GetSubFolders(folder) & "</UL>"