---
title: "Förhindra långa ord"
type: "forum-thread"
url: "https://www.webforum.nu/amne/asp/101775-förhindra-långa-ord"
topic: "ASP"
topic_url: "https://www.webforum.nu/amne/asp"
author: "Erik Juhlin"
published: "2004-04-18T17:24:00.000Z"
updated: "2006-04-17T11:24:45.000Z"
replies: 2
views: 6278
page: 1
pages: 1
language: "sv-SE"
site: "webForum — webforum.nu"
rights: "Upphovsrätten till varje inlägg tillhör dess författare."
attribution: "Citera som: webForum, https://www.webforum.nu/amne/asp/101775-förhindra-långa-ord"
---

# Förhindra långa ord

## #1 — Erik Juhlin, 2004-04-18T17:24Z

Här kommer två sätt för hur man kan hindra långa ord som tvingar fram sidscrollen. Gör dessa för att jag sett så väldigt många konstiga lösningar.

```
<%
Option Explicit

Function ShorterString1(ByVal sString, ByVal lMaxLength)
	Dim objRegExp
	Set objRegExp = New RegExp
	objRegExp.Global = True
	objRegExp.Pattern = "(\S{" & lMaxLength & "})"
	ShorterString1 = objRegExp.Replace(sString, "$1 ")
	Set objRegExp = Nothing
End Function

Response.Write ShorterString1("sdfsdfdssfdfvdgdgfsfggfgfgfgffgfdfgfggfdggfgfgfdgdffdfggffggfgfgfgfdfs lalalal eoeooeoe", 5) & "<br>"

Function ShorterString2(ByVal sString, ByVal lMaxLength)
	Dim objRegExp
	Set objRegExp = New RegExp
	objRegExp.Global = True
	objRegExp.Pattern = "(\S{" & lMaxLength & ",})"
	ShorterString2 = objRegExp.Replace(sString, "<span style=""word-break: break-all;"">$1</span>")
	Set objRegExp = Nothing
End Function

Response.Write ShorterString2("sdfsdfdssfdfvdgdgfsfggfgfgfgffgfdfgfggfdggfgfgfdgdffdfggffggfgfgfgfdfs lalalal eoeooeoe", 5)
%>
```

Den första sätter in mellanslag efter X antal tecken utan mellanslag. kan bli dubbla mellanslag om ordet är lika långt som maxlängden, men det bör inte spela någon roll eftersom att det inte visas som två mellanslag på en webbsida.
Den andra sätter in en span-tagg runt det långa ordet med CSS-attributet word-break: break-all;. Detta gör att det kommer att radbrytas när det behövs, men inga mellanslag visas. Lätt snyggaste lösningen, men lite trixig om man vill kombinera den med Server.HTMLEncode...

Permalänk: https://www.webforum.nu/p/101775

## #2 — NEOLiNES, 2005-01-18T00:22Z

Mycket najs! Tack! :P

Permalänk: https://www.webforum.nu/p/1531777

## #3 — medialabs, 2006-04-17T11:24Z

//Red.

skrev i fel tråd  :OO

Permalänk: https://www.webforum.nu/p/1800957

---

Tråden på webben: https://www.webforum.nu/amne/asp/101775-förhindra-långa-ord