---
title: "Enkel Kalender kod?"
type: "forum-thread"
url: "https://www.webforum.nu/amne/asp/100884-enkel-kalender-kod"
topic: "ASP"
topic_url: "https://www.webforum.nu/amne/asp"
author: "voigtann1"
published: "2004-04-04T11:47:49.000Z"
updated: "2004-04-05T18:12:40.000Z"
replies: 8
views: 495
page: 1
pages: 1
language: "sv-SE"
site: "webForum — webforum.nu"
rights: "Upphovsrätten till varje inlägg tillhör dess författare."
attribution: "Citera som: webForum, https://www.webforum.nu/amne/asp/100884-enkel-kalender-kod"
---

# Enkel Kalender kod?

## #1 — voigtann1, 2004-04-04T11:47Z

Funderade på att göra en egen kalender fast har bara hittat färdiga koder med mer saker än jag egentligen vill ha... har någon en kod som är så simpel som möjligt för att kunna se hela månaden som en vanlig kalender?

Permalänk: https://www.webforum.nu/p/100884

## #2 — Poffe, 2004-04-04T11:53Z

Hmm.. Om du ska göra en egen kalender som du nu skriver ska du väll inte ta någon annans kod?

Permalänk: https://www.webforum.nu/p/1314024

## #3 — voigtann1, 2004-04-04T12:02Z

Det är sant :D Det jag hade tänkt mig var mer än bas kod som man kan ändra så den uppfyller ens syfte :D

Permalänk: https://www.webforum.nu/p/1314026

## #4 — Mini-Harry, 2004-04-04T13:12Z

Om du verkligen vill ha en kalender precis så som du vill ha den, är det väl bäst att göra en egen helt från grunden? Det är inte så svårt och så får du den att se ut precis som du själv vill ha den.

Permalänk: https://www.webforum.nu/p/1314046

## #5 — Sebbe, 2004-04-04T14:05Z

Visar månaden för dtmDate (som det är nu är det den här månaden):

```
<html>
  <body>
    <table border="1">
      <tr>
<%
dtmDate = Date()

For i = 1 To WeekDay(DateSerial(Year(dtmDate), Month(dtmDate), "01"), vbMonday) - 1
  Response.Write("        <td>&amp;nbsp;</td>" & vbCrLf)
  intCount = intCount + 1
Next

intDays = Day(DateAdd("d", -1, DateAdd("m", 1, DateSerial(Year(dtmDate), Month(dtmDate), "01"))))

For i = 1 To intDays
  If intCount Mod 7 = 0 AND intCount > 0 Then Response.Write("      </tr><tr>" & vbCrLf)

  Response.Write("        <td>" & i & "</td>" & vbCrLf)
  intCount = intCount + 1
Next

If intCount Mod 7 > 0 Then
  For i = (intCount Mod 7) + 1 To 7
    Response.Write("        <td>&nbsp;</td>" & vbCrLf)
  Next
End If
%>
      </tr>
    </table>
  </body>
</html>
```

**/red** Litet fel bara, man ska inte skriva koder utan att testa dem först. ;)

Permalänk: https://www.webforum.nu/p/1314063

## #6 — voigtann1, 2004-04-04T17:30Z

Sebbe: Hur gör jag för att få den 1:a tex april skrivas ut vid en tabell för Torsdag.... med kanske en tjock text för denna månad och om man kollar på den första dagarna innan Torsdagen den 1: april....

Permalänk: https://www.webforum.nu/p/1314128

## #7 — Sebbe, 2004-04-04T17:50Z

Det sista du sa fattade jag inte ett ord av, men med det första antar jag att du menade ungefär såhär?

```
<html>
  <body>
    <table border="1">
      <tr>
        <th>Måndag</th>
        <th>Tisdag</th>
        <th>Onsdag</th>
        <th>Torsdag</th>
        <th>Fredag</th>
        <th>Lördag</th>
        <th>Söndag</th>
      </tr>
      <tr>
<%
dtmDate = Date()

For i = 1 To WeekDay(DateSerial(Year(dtmDate), Month(dtmDate), "01"), vbMonday) - 1
  Response.Write("        <td>&nbsp;</td>" & vbCrLf)
  intCount = intCount + 1
Next

intDays = Day(DateAdd("d", -1, DateAdd("m", 1, DateSerial(Year(dtmDate), Month(dtmDate), "01"))))

For i = 1 To intDays
  If intCount Mod 7 = 0 AND intCount > 0 Then Response.Write("      </tr><tr>" & vbCrLf)

  Response.Write("        <td>" & i & "</td>" & vbCrLf)
  intCount = intCount + 1
Next

If intCount Mod 7 > 0 Then
  For i = (intCount Mod 7) + 1 To 7
    Response.Write("        <td> </td>" & vbCrLf)
  Next
End If
%>
      </tr>
    </table>
  </body>
</html>
```

Permalänk: https://www.webforum.nu/p/1314137

## #8 — voigtann1, 2004-04-05T17:32Z

Det jag ville ha var typ:

APRIL
M \| T \| O \| T \| F \| L \| S
\--------------------------------------
**28\|29\|30**\| 1\| 2\| 3\| 4

Eftersom 1a april börjar på en torsdag vill jag ändå ha 28-\>30 från förra månaden kvar...

Permalänk: https://www.webforum.nu/p/1317465

## #9 — Sebbe, 2004-04-05T18:12Z

Nu ska det nog vara rätt. :)

```
<html>
  <body>
    <table border="1">
      <tr>
        <th>Måndag</th>
        <th>Tisdag</th>
        <th>Onsdag</th>
        <th>Torsdag</th>
        <th>Fredag</th>
        <th>Lördag</th>
        <th>Söndag</th>
      </tr>
      <tr>
<%
dtmDate = Date()
dtmPrevious = DateAdd("m", -1, dtmDate)
intPrevious = Day(DateAdd("d", -1, DateAdd("m", 1, DateSerial(Year(dtmPrevious), Month(dtmPrevious), "01"))))
intPrevious = intPrevious - (WeekDay(DateSerial(Year(dtmDate), Month(dtmDate), "01"), vbMonday) - 2)

For i = 1 To WeekDay(DateSerial(Year(dtmDate), Month(dtmDate), "01"), vbMonday) - 1
  Response.Write("        <td style=""color: #AAAAAA"">" & intPrevious & "</td>" & vbCrLf)
  intCount = intCount + 1
  intPrevious = intPrevious + 1
Next

intDays = Day(DateAdd("d", -1, DateAdd("m", 1, DateSerial(Year(dtmDate), Month(dtmDate), "01"))))

For i = 1 To intDays
  If intCount Mod 7 = 0 AND intCount > 0 Then Response.Write("      </tr><tr>" & vbCrLf)

  Response.Write("        <td>" & i & "</td>" & vbCrLf)
  intCount = intCount + 1
Next

If intCount Mod 7 > 0 Then
  For i = (intCount Mod 7) + 1 To 7
    intNext = intNext + 1
    Response.Write("        <td style=""color: #AAAAAA"">" & intNext & "</td>" & vbCrLf)
  Next
End If
%>
      </tr>
    </table>
  </body>
</html>
```

Permalänk: https://www.webforum.nu/p/1317493

---

Tråden på webben: https://www.webforum.nu/amne/asp/100884-enkel-kalender-kod