8 svar · 488 visningar · startad av voigtann1
Funderade på att göra en egen kalender fast har bara hittat färdiga koder med mer saker än jag egentligen vill ha... har någon en kod som är så simpel som möjligt för att kunna se hela månaden som en vanlig kalender?
Hmm.. Om du ska göra en egen kalender som du nu skriver ska du väll inte ta någon annans kod?
Det är sant :D Det jag hade tänkt mig var mer än bas kod som man kan ändra så den uppfyller ens syfte :D
Om du verkligen vill ha en kalender precis så som du vill ha den, är det väl bäst att göra en egen helt från grunden? Det är inte så svårt och så får du den att se ut precis som du själv vill ha den.
Visar månaden för dtmDate (som det är nu är det den här månaden):
<html>
<body>
<table border="1">
<tr>
<%
dtmDate = Date()
For i = 1 To WeekDay(DateSerial(Year(dtmDate), Month(dtmDate), "01"), vbMonday) - 1
Response.Write(" <td>&nbsp;</td>" & vbCrLf)
intCount = intCount + 1
Next
intDays = Day(DateAdd("d", -1, DateAdd("m", 1, DateSerial(Year(dtmDate), Month(dtmDate), "01"))))
For i = 1 To intDays
If intCount Mod 7 = 0 AND intCount > 0 Then Response.Write(" </tr><tr>" & vbCrLf)
Response.Write(" <td>" & i & "</td>" & vbCrLf)
intCount = intCount + 1
Next
If intCount Mod 7 > 0 Then
For i = (intCount Mod 7) + 1 To 7
Response.Write(" <td> </td>" & vbCrLf)
Next
End If
%>
</tr>
</table>
</body>
</html>
/red Litet fel bara, man ska inte skriva koder utan att testa dem först. ;)
Sebbe: Hur gör jag för att få den 1:a tex april skrivas ut vid en tabell för Torsdag.... med kanske en tjock text för denna månad och om man kollar på den första dagarna innan Torsdagen den 1: april....
Det sista du sa fattade jag inte ett ord av, men med det första antar jag att du menade ungefär såhär?
<html>
<body>
<table border="1">
<tr>
<th>Måndag</th>
<th>Tisdag</th>
<th>Onsdag</th>
<th>Torsdag</th>
<th>Fredag</th>
<th>Lördag</th>
<th>Söndag</th>
</tr>
<tr>
<%
dtmDate = Date()
For i = 1 To WeekDay(DateSerial(Year(dtmDate), Month(dtmDate), "01"), vbMonday) - 1
Response.Write(" <td> </td>" & vbCrLf)
intCount = intCount + 1
Next
intDays = Day(DateAdd("d", -1, DateAdd("m", 1, DateSerial(Year(dtmDate), Month(dtmDate), "01"))))
For i = 1 To intDays
If intCount Mod 7 = 0 AND intCount > 0 Then Response.Write(" </tr><tr>" & vbCrLf)
Response.Write(" <td>" & i & "</td>" & vbCrLf)
intCount = intCount + 1
Next
If intCount Mod 7 > 0 Then
For i = (intCount Mod 7) + 1 To 7
Response.Write(" <td> </td>" & vbCrLf)
Next
End If
%>
</tr>
</table>
</body>
</html>
Det jag ville ha var typ:
APRIL
M | T | O | T | F | L | S
--------------------------------------
28|29|30| 1| 2| 3| 4
Eftersom 1a april börjar på en torsdag vill jag ändå ha 28->30 från förra månaden kvar...
Nu ska det nog vara rätt. :)
<html>
<body>
<table border="1">
<tr>
<th>Måndag</th>
<th>Tisdag</th>
<th>Onsdag</th>
<th>Torsdag</th>
<th>Fredag</th>
<th>Lördag</th>
<th>Söndag</th>
</tr>
<tr>
<%
dtmDate = Date()
dtmPrevious = DateAdd("m", -1, dtmDate)
intPrevious = Day(DateAdd("d", -1, DateAdd("m", 1, DateSerial(Year(dtmPrevious), Month(dtmPrevious), "01"))))
intPrevious = intPrevious - (WeekDay(DateSerial(Year(dtmDate), Month(dtmDate), "01"), vbMonday) - 2)
For i = 1 To WeekDay(DateSerial(Year(dtmDate), Month(dtmDate), "01"), vbMonday) - 1
Response.Write(" <td style=""color: #AAAAAA"">" & intPrevious & "</td>" & vbCrLf)
intCount = intCount + 1
intPrevious = intPrevious + 1
Next
intDays = Day(DateAdd("d", -1, DateAdd("m", 1, DateSerial(Year(dtmDate), Month(dtmDate), "01"))))
For i = 1 To intDays
If intCount Mod 7 = 0 AND intCount > 0 Then Response.Write(" </tr><tr>" & vbCrLf)
Response.Write(" <td>" & i & "</td>" & vbCrLf)
intCount = intCount + 1
Next
If intCount Mod 7 > 0 Then
For i = (intCount Mod 7) + 1 To 7
intNext = intNext + 1
Response.Write(" <td style=""color: #AAAAAA"">" & intNext & "</td>" & vbCrLf)
Next
End If
%>
</tr>
</table>
</body>
</html>