Fso sökfunktion — webForum

VideMedlem sedan dec. 19998 577 inlägg

11 juli 2000 07:09#1

Detta är ett skript som söker igenom en mapp efter söksträngen ifrån sida 1. Som det är inställt nu så letar den igenom wwwroot, Set objFolder = objFSO.GetFolder(Server.MapPath("/"))
du kan ändra detta till en vilken mapp du vill.

Skriptet finnes på http://www.4guysfromrolla.com

Search.asp

<HTML>
<BODY>
<FORM METHOD=POST ACTION="TextSearch.asp">
  Enter text to search for:
  <INPUT TYPE=TEXT NAME=SearchText>
  <P>
  <INPUT TYPE=SUBMIT VALUE="Begin Search!">
</FORM>
</BODY>
</HTML>

TextSearch.asp

<HTML><BODY>
<B>Search Results for <%=Request("SearchText")%></B><BR>

<%
Const fsoForReading = 1

Dim strSearchText
strSearchText = Request("SearchText")

'Now, we want to search all of the files
Dim objFSO
Set objFSO = Server.CreateObject("Scripting.FileSystemObject")

Dim objFolder
Set objFolder = objFSO.GetFolder(Server.MapPath("/"))

Dim objFile, objTextStream, strFileContents, bolFileFound
bolFileFound = False

For Each objFile in objFolder.Files
  If Response.IsClientConnected then
    Set objTextStream = objFSO.OpenTextFile(objFile.Path,fsoForReading)

    strFileContents = objTextStream.ReadAll

    If InStr(1,strFileContents,strSearchText,1) then
       Response.Write "<LI><A HREF=""/" & objFile.Name & _
                      """>" & objFile.Name & "</A><BR>"

       bolFileFound = True
    End If

    objTextStream.Close
  End If
Next

if Not bolFileFound then Response.Write "No matches found..."

Set objTextStream = Nothing
Set objFolder = Nothing
Set objFSO = Nothing
%>
</BODY></HTML>

------------------
Vides motto: Ju fler saker man tycker är roligt, desto roligare har man
www.webeye.nu

[Ej Redigerat av Bire den 31 jan 1956]

Dock av Vide:

[Redigerat av Vide den 11 jul 2000]