Lista all info ur en tabell inkl fältnamnen

Hej!

Jag söker efter ett skript som skriver ut allt innehåll ur en tabell, det har funnits här innan, men jag kan inte hitta det.

Är det nån som har en kopia på det?

MVH
David

Snabbexempel a´la MS Access:

[red]Set Connect = Server.CreateObject("ADODB.Connection")
	Connect.Open "Provider=Microsoft.Jet.OLEDB.4.0;Data Source ="& Server.MapPath("databas.mdb")
		Set RecSet = Connect.Execute("SELECT * FROM tabell")

			If NOT RecSet.EOF Then
				Do Until RecSet.EOF
					Response.Write RecSet("KOLUMNENS_NAMN") &"<br>"
					RecSet.MoveNext
				Loop
			Else
				Response.Write "Det finns inget att skriva ut."
			End If
			RecSet.Close

		Set RecSet = Nothing
	Connect.Close
Set Connect = Nothing[/red]

Eftersom jag tror att Palle missuppfattade frågan så modifierar jag hans exempel en aning. ;)

Set Connect = Server.CreateObject("ADODB.Connection")
Connect.Open "Provider=Microsoft.Jet.OLEDB.4.0;Data Source ="& Server.MapPath("databas.mdb")
Set RecSet = Connect.Execute("SELECT * FROM tabell")
If NOT RecSet.EOF Then
	Response.write "<table><tr>"
	For i = 0 to RecSet.Fields.Count -1
		Response.write "<th>" & RecSet.Fields(i).Name & "</th>"
	Next
	Response.write "</tr>"
	Do Until RecSet.EOF
		Response.write "<tr>"
		For i = 0 to RecSet.Fields.Count -1
			Response.Write "<td>" & RecSet.Fields(i).Value & "</td>"
		Next
		Response.write "</tr>"
		RecSet.MoveNext
	Loop
	Response.write "</table>"
Else
	Response.Write "Det finns inget att skriva ut."
End If
RecSet.Close
Set RecSet = Nothing
Connect.Close
Set Connect = Nothing

Helt otestat, naturligtvis.

(Jag var inte helt nöjt med Palles indentering heller, som synes. ;-) )

mvh