Annan ordning på poster i loop...

Har en tabell på min sida där olika kategorier radas upp i följande ordning:

A B C
D E F
G H I
J K L

osv.....

Jag vill att det ska radas upp på följande vis istället:

A E I
B F J
C G K
D H L

osv....

Denna kod radar upp så som det ser ut nu

<%
numcols=3
if not objRS2.eof then   
%>
              <table width="600" cellspacing="0" cellpadding="2" border="0" bgcolor="#CCCCCC">
                <%
do until objRS2.eof%>
                <tr>
<%    
for i=1 to numcols 
%>       
<td class="tabell" width="200" valign="top">
<%       
 if objRS2.eof then         
%>    
    <% else%>
INNEHÅLLET I KOLUMNERNA HÄR
<%objRS2.movenext   
      end if     
%> 
</td> 
<% next %> 
</tr>
<%
 loop  %>
</table>
<%end if%>

Hoppas att någon kan hjälpa.. :h

------------------
Det är lättare att leva ett rikt liv som ung, när man vet att det väntar ett som gammal
E-post

Vil du låsa antalet kolumner eller antalet rader?

Kolumnerna är juh redan låsta till 3st.. :)

Men jag vill ändra ordningen på resultatet som visas..

Som jag har visat på mitt första inlägg så radas posterna från vänster till höger 3st och sedan ett "hopp" ned osv..

Jag vill att det istället ska radas uppifrån och ner, från rad1 till rad4..

Fast kolumnerna ska vara låsta till 3! :h

------------------
Det är lättare att leva ett rikt liv som ung, när man vet att det väntar ett som gammal
E-post

Det löser du ju enkelt med en tabell

<table>
<tr>
<td>
SQL = SQL ...   AND Efternamn LIKE '[A-D]%'

Lista resultat...

</td><td>

SQL = SQL ...   AND Efternamn LIKE '[E-H]%'

Lista resultat...

</td><td>

SQL = SQL ...   AND Efternamn LIKE '[I-L]%'

Lista resultat...

</td>

Det finns säkert något fiffigt annat sätt du kan lösa det på också men inget jag känner till. :)

//JANspeed

Har haru lite kod som du kan använda.

rs ersätter du med ditt eget recordset, och i arrFields(0,intCurPos-1) motsvarar 0:an den första kolumnen i utsökningen

numcols=3
if not rs.eof then   
	arrFields=rs.getrows
	intCount=ubound(arrFields,2)+1
	numrows=ceil(intCount/numcols)

	response.write "<TABLE>"   
	for j=1 to numrows      
		response.write "<TR>"      
		for i=1 to numcols         
			intCurPos=numrows*(i-1)+j
			response.write "<TD>"         
			if  intCurPos>intCount then       
				response.write "&nbsp;"         
			else            
				response.write arrFields(0,intCurPos-1)            
			end if         
			response.write "</TD>"      
		next      
		response.write "</TR>"   
	next   
	response.write "</TABLE>"
end if

function ceil(dblValue)
	intTest=int(dblValue)
	if intTest<dblValue then
		ceil=intTest+1
	else
		ceil=intTest
	end if
end function